[#Part: CMP TallyShopFeatures Left]
	Add : Line  : 	 Enable_TrackeInvoiceStatus

[Line :  Enable_TrackeInvoiceStatus]
    Field : medium prompt, Enable_TrackeInvoiceStatus
    Local : Field : medium prompt : set as : "Show e-Invoice Status in Sales Register ?"
    Local : Field : Medium Prompt : width : 35
    space top : 0.2 cm
	
[Field :  Enable_TrackeInvoiceStatus]
    Use : Logical field
    Storage : Enable_TrackeInvoiceStatus
	
[System: formula]
	Enable_TrackeInvoiceStatus : $Enable_TrackeInvoiceStatus:company:##svcurrentcompany
	
[System: udf]
	Enable_TrackeInvoiceStatus	: Logical	: 1120
	

[#Collection : Filtered Vouchers of Company]
	Option 	: CC_eInvoiceStatusSearch	: @@Enable_TrackeInvoiceStatus

[#Collection: Columnar Filtered Vouchers of Company]
	Option 	: CC_eInvoiceStatusSearch	: @@Enable_TrackeInvoiceStatus

[#Collection : Day Book Vouchers of Company]
	Option 	: CC_eInvoiceStatusSearch	: @@Enable_TrackeInvoiceStatus

[#Collection: Vouchers of Ledger]
	Option 	: CC_eInvoiceStatusSearch	: @@Enable_TrackeInvoiceStatus

[!Collection 	: CC_eInvoiceStatusSearch]
	Filter		: CC_eInvoiceStatusSearch
	Filter		: DAS_eInvoiceStatus_All
	
	Fetch		: IRNQRCode ,IRN ,IRNCancelled 
	
[System: formula]
	CC_eInvoiceStatusSearch : if $$IsSysName:##CC_eInvoiceStatusSearch then YES else @@IsGSTeInvVchStatus = ##CC_eInvoiceStatusSearch

		
[Variable : DAS_eInvoiceStatus_StatusVar]
	Type	: String

[#Form: Normal Day Book]
	Add:Option:vvvnEnable_TrackeInvoiceStatus : @@Enable_TrackeInvoiceStatus
	
[!Form:vvvnEnable_TrackeInvoiceStatus]
    
	Add:Part:At Beginning:DAS_eInvoiceStatus_Status
	
[Part : DAS_eInvoiceStatus_Status]
	Space Bottom	: 2 mm
	Space Top		: 1 mm
	Horizontal Align:Centre

	Line	: DAS_eInvoiceStatus_StatusTitle
	Line	: DAS_eInvoiceStatus_StatusDetails
	
	Invisible:@@InPrintORExcelExportMode OR NOT ##Show_eInvoiceStatusSalesRegister
	
		
	Local 	: Field : DAS_eInvoiceStatus_Pending_Click 					: Width		: 9
	Local 	: Field : DAS_eInvoiceStatus_GeneratedwithQRCode_Click 		: Width		: 20
	Local 	: Field : DAS_eInvoiceStatus_PendingforGeneration_Click 	: Width		: 20
	Local 	: Field : DAS_eInvoiceStatus_GeneratedwithoutQRCode_Click 	: Width		: 20
	Local 	: Field : DAS_eInvoiceStatus_Rejected_Click 				: Width		: 9
	Local 	: Field : DAS_eInvoiceStatus_Cancelled_Click				: Width		: 9
	Local 	: Field : DAS_eInvoiceStatus_NotApplicable_Click 			: Width		: 12
	
[Line	: DAS_eInvoiceStatus_StatusTitle]
	Use		: DAS_eInvoiceStatus_StatusDetails
					
	Local	: Field	: Default	: Type		: String
			
	Local	: Field	: DAS_eInvoiceStatus_Pending_Click					: Set as	: "No of Sales"
	Local	: Field	: DAS_eInvoiceStatus_GeneratedwithQRCode_Click		: Set as	: "Generated with QR Code"
	Local	: Field	: DAS_eInvoiceStatus_GeneratedwithoutQRCode_Click	: Set as	: "Generated without QR Code"
	Local	: Field	: DAS_eInvoiceStatus_PendingforGeneration_Click		: Set as	: "Pending for Generation"
	Local	: Field	: DAS_eInvoiceStatus_Rejected_Click					: Set as	: "Rejected"
	Local	: Field	: DAS_eInvoiceStatus_Cancelled_Click				: Set as	: "Cancelled"
	Local	: Field	: DAS_eInvoiceStatus_NotApplicable_Click			: Set as	: "Not Applicable"
	
[Line	: DAS_eInvoiceStatus_StatusDetails]	
	Local 	: Field : Default : ToolTip 	: "Click Hare to Change Status Filter"
	
	Field	: DAS_eInvoiceStatus_Pending_Click
	Field	: DAS_eInvoiceStatus_GeneratedwithQRCode_Click
	
	Field	: DAS_eInvoiceStatus_GeneratedwithoutQRCode_Click
	Field	: DAS_eInvoiceStatus_PendingforGeneration_Click
	Field	: DAS_eInvoiceStatus_Rejected_Click
	Field	: DAS_eInvoiceStatus_Cancelled_Click
	Field	: DAS_eInvoiceStatus_NotApplicable_Click
	
;; All
[Field : DAS_eInvoiceStatus_Pending_Click]
	Set as	: $$FilterCount:DAS_eInvoiceStatus_TotalColl
	Set Always:Yes
	Skip	: Yes
	Border	: Thin box
	Align	: Centre
	Style	: Small
	Key		: DAS_eInvoiceStatus_Pending_Click
	
	Option	: DAS_eInvoiceStatus_NotClickAction	: @@DAS_eInvoiceStatus_StatusVar_Clr
	Option	: DAS_eInvoiceStatus_ClickAction	: ##DAS_eInvoiceStatus_StatusVar = $$SysName:AllItems
						
[Key : DAS_eInvoiceStatus_Pending_Click]
	Key			: Left Click
	ActionList	: DAS_eInvoiceStatus_Pending_Click 2
	ActionList	: DAS_eInvoiceStatus_ClickRefresh
	
[Key	: DAS_eInvoiceStatus_Pending_Click 2]
	Key     : Left Click
	Action	: Set	: DAS_eInvoiceStatus_StatusVar	: $$SysName:AllItems
	
;; GeneratedwithQRCode
[Field : DAS_eInvoiceStatus_GeneratedwithQRCode_Click]
	Use		: Number Field
	Set as	: $$FilterCount:DAS_eInvoiceStatus_TotalColl:DAS_eInvoiceStatus_GeneratedwithQRCode
	Border	: Thin box
	Align	: Centre
	Style	: Small
	Key		: DAS_eInvoiceStatus_GeneratedwithQRCode_Click
	
	Option	: DAS_eInvoiceStatus_NotClickAction	: @@DAS_eInvoiceStatus_StatusVar_Clr
	Option	: DAS_eInvoiceStatus_ClickAction	: ##DAS_eInvoiceStatus_StatusVar = "Generated with QR Code"
	
[Key : DAS_eInvoiceStatus_GeneratedwithQRCode_Click]
	Key			: Left Click
	ActionList	: DAS_eInvoiceStatus_GeneratedwithQRCode_Click 2
	ActionList	: DAS_eInvoiceStatus_ClickRefresh
	
[Key	: DAS_eInvoiceStatus_GeneratedwithQRCode_Click 2]
	Key     : Left Click
	Action	: Set	: DAS_eInvoiceStatus_StatusVar	: "Generated with QR Code"

;; Items
[Field : DAS_eInvoiceStatus_GeneratedwithoutQRCode_Click]
	Use		: Number Field
	Set as	: $$FilterCount:DAS_eInvoiceStatus_TotalColl:DAS_eInvoiceStatus_GeneratedwithoutQRCode
	Border	: Thin box
	Align	: Centre
	Style	: Small
	Key		: DAS_eInvoiceStatus_GeneratedwithoutQRCode_Click
	
	Option	: DAS_eInvoiceStatus_NotClickAction	: @@DAS_eInvoiceStatus_StatusVar_Clr
	Option	: DAS_eInvoiceStatus_ClickAction_GeneratedwithoutQRCode	: ##DAS_eInvoiceStatus_StatusVar = "Generated without QR Code"
	
[!Field : DAS_eInvoiceStatus_ClickAction_GeneratedwithoutQRCode]
	Add	: Background	: RulerGrey
	Add	: Color			: White
	Add	: Style			: Small Bold
	

[Key : DAS_eInvoiceStatus_GeneratedwithoutQRCode_Click]
	Key			: Left Click
	ActionList	: DAS_eInvoiceStatus_GeneratedwithoutQRCode_Click 2
	ActionList	: DAS_eInvoiceStatus_ClickRefresh
	
[Key	: DAS_eInvoiceStatus_GeneratedwithoutQRCode_Click 2]
	Key     : Left Click
	Action	: Set	: DAS_eInvoiceStatus_StatusVar	: "Generated without QR Code"

;; PendingforGeneration
[Field : DAS_eInvoiceStatus_PendingforGeneration_Click]
	Use		: Number Field
	Set as	: $$FilterCount:DAS_eInvoiceStatus_TotalColl:DAS_eInvoiceStatus_PendingforGeneration
	Border	: Thin box
	Align	: Centre
	Style	: Small
	Key		: DAS_eInvoiceStatus_PendingforGeneration_Click
	
	Option	: DAS_eInvoiceStatus_NotClickAction	: @@DAS_eInvoiceStatus_StatusVar_Clr
	Option	: DAS_eInvoiceStatus_ClickAction_PendingforGeneration	: ##DAS_eInvoiceStatus_StatusVar = "Pending for Generation"
	
[!Field : DAS_eInvoiceStatus_ClickAction_PendingforGeneration]
	Add	: Background	: Blue
	Add	: Color			: White
	Add	: Style			: Small Bold

[Key : DAS_eInvoiceStatus_PendingforGeneration_Click]
	Key			: Left Click
	ActionList	: DAS_eInvoiceStatus_PendingforGeneration_Click 2
	ActionList	: DAS_eInvoiceStatus_ClickRefresh
	
[Key	: DAS_eInvoiceStatus_PendingforGeneration_Click 2]
	Key     : Left Click
	Action	: Set	: DAS_eInvoiceStatus_StatusVar	: "Pending for Generation"

[Key	: DAS_eInvoiceStatus_ClickRefresh]
	Key     : Left Click
	Action	: Refresh Data

;; Rejected
[Field : DAS_eInvoiceStatus_Rejected_Click]
	Use		: Number Field
	Set as	: $$FilterCount:DAS_eInvoiceStatus_TotalColl:DAS_eInvoiceStatus_Rejected
	Border	: Thin box
	Align	: Centre
	Style	: Small
	Key		: DAS_eInvoiceStatus_Rejected_Click
	
	Option	: DAS_eInvoiceStatus_NotClickAction	: @@DAS_eInvoiceStatus_StatusVar_Clr
	Option	: DAS_eInvoiceStatus_ClickAction_Rejected	: ##DAS_eInvoiceStatus_StatusVar = "Rejected"

[!Field : DAS_eInvoiceStatus_ClickAction_Rejected]
	Add	: Background	: Red
	Add	: Color			: White
	Add	: Style			: Small Bold

[Key : DAS_eInvoiceStatus_Rejected_Click]
	Key			: Left Click
	ActionList	: DAS_eInvoiceStatus_Rejected_Click 2
	ActionList	: DAS_eInvoiceStatus_ClickRefresh
	
[Key	: DAS_eInvoiceStatus_Rejected_Click 2]
	Key     : Left Click
	Action	: Set	: DAS_eInvoiceStatus_StatusVar	: "Rejected"
	
;; Cancelled
[Field : DAS_eInvoiceStatus_Cancelled_Click]
	Use		: Number Field
	Set as	: $$FilterCount:DAS_eInvoiceStatus_TotalColl:DAS_eInvoiceStatus_Cancelled
	Border	: Thin box
	Align	: Centre
	Style	: Small
	Key		: DAS_eInvoiceStatus_Cancelled_Click
	
	Option	: DAS_eInvoiceStatus_NotClickAction	: @@DAS_eInvoiceStatus_StatusVar_Clr
	Option	: DAS_eInvoiceStatus_ClickAction_Cancelled	: ##DAS_eInvoiceStatus_StatusVar = "Cancelled"
	
[!Field : DAS_eInvoiceStatus_ClickAction_Cancelled]
	Add	: Background	: DAS_eInvoiceStatus_StatusVar_BG
	Add	: Color			: White
	Add	: Style			: Small Bold

[Key : DAS_eInvoiceStatus_Cancelled_Click]
	Key			: Left Click
	ActionList	: DAS_eInvoiceStatus_Cancelled_Click 2
	ActionList	: DAS_eInvoiceStatus_ClickRefresh
	
[Key	: DAS_eInvoiceStatus_Cancelled_Click 2]
	Key     : Left Click
	Action	: Set	: DAS_eInvoiceStatus_StatusVar	: "Cancelled"
	
;; NotApplicable
[Field : DAS_eInvoiceStatus_NotApplicable_Click]
	Use		: Number Field
	Set as	: $$FilterCount:DAS_eInvoiceStatus_TotalColl:DAS_eInvoiceStatus_NotApplicable
	Border	: Thin box
	Align	: Centre
	Style	: Small
	Key		: DAS_eInvoiceStatus_NotApplicable_Click
	
	Option	: DAS_eInvoiceStatus_NotClickAction	: @@DAS_eInvoiceStatus_StatusVar_Clr
	Option	: DAS_eInvoiceStatus_ClickAction_NotApplicable	: ##DAS_eInvoiceStatus_StatusVar = "Not Applicable"
			
[!Field : DAS_eInvoiceStatus_ClickAction_NotApplicable]
	Add	: Background	: DarkGreen
	Add	: Color			: White
	Add	: Style			: Small Bold
	
	
[Key : DAS_eInvoiceStatus_NotApplicable_Click]
	Key			: Left Click
	ActionList	: DAS_eInvoiceStatus_NotApplicable_Click 2
	ActionList	: DAS_eInvoiceStatus_ClickRefresh
	
[Key	: DAS_eInvoiceStatus_NotApplicable_Click 2]
	Key     : Left Click
	Action	: Set	: DAS_eInvoiceStatus_StatusVar	: "Not Applicable"
	
[System:Formulas]
	DAS_eInvoiceStatus_StatusVar_Clr  : NOT ##DAS_eInvoiceStatus_StatusVar = $$SysName:AllItems OR ##DAS_eInvoiceStatus_StatusVar = $$SysName:AllItems
	
[!Field : DAS_eInvoiceStatus_NotClickAction]
	Add	: Background	: Released Blue	
	Add	: Color			: Black
	Add	: Style			: Small Bold
	;Add : Print BG		: Released Blue	
	;Add : Print FG		: Black
								
[!Field : DAS_eInvoiceStatus_ClickAction]
	Add	: Background	: DAS_eInvoiceStatus_StatusVar_BG
	Add	: Color			: White
	Add	: Style			: Small Bold

[Color: DAS_eInvoiceStatus_StatusVar_BG]
	RGB	: 30,70,37

[Collection: DAS_eInvoiceStatus_TotalColl]
	Source Collection	: SRC Filtered Vouchers of Company
	
    Fetch       : Date, VoucherNumber, Reference, VoucherTypeName, SortPosition, Narration, PartyLedgerName, PartyName, BasicBuyerName, IsEditLogPresent, IsAuditedVchModified
	Fetch		: IsOptional, IsPostDated, MasterID, IsCancelled, IsDeleted
	Fetch		: AllLedgerEntries.IsDeemedPositive ;;For POS Transaction Value
	Fetch		: AllLedgerEntries.HasBankAllocations, AllInventoryEntries.BatchAllocations.OrderNo
	Fetch		: AllInventoryEntries.BatchAllocations.TrackingNumber

	Fetch		: IRNQRCode ,IRN ,IRNCancelled 

[System: formula]
	DAS_eInvoiceStatus_All 						: IF ##DAS_eInvoiceStatus_StatusVar = $$SysName:AllItems THEN Yes ELSE  @@IsGSTeInvVchStatus = ##DAS_eInvoiceStatus_StatusVar
	
	DAS_eInvoiceStatus_GeneratedwithQRCode 		: @@IsGSTeInvVchStatus = "Generated with QR Code"
	DAS_eInvoiceStatus_PendingforGeneration		: @@IsGSTeInvVchStatus = "Pending for Generation"
	
	DAS_eInvoiceStatus_GeneratedwithoutQRCode 	: @@IsGSTeInvVchStatus = "Generated without QR Code"
	DAS_eInvoiceStatus_Rejected 				: @@IsGSTeInvVchStatus = "Rejected"
	DAS_eInvoiceStatus_Cancelled				: @@IsGSTeInvVchStatus = "Cancelled"
	DAS_eInvoiceStatus_NotApplicable 			: @@IsGSTeInvVchStatus = "Not Applicable" 
	


[#Line: DBTitle1]
	Add:Option:vvvnEnable_TrackeInvoiceStatus:@@Enable_TrackeInvoiceStatus

[#Line: DBTitle2]
	Add:Option:vvvnEnable_TrackeInvoiceStatusvv:@@Enable_TrackeInvoiceStatus
	
[!Line:vvvnEnable_TrackeInvoiceStatusvv]
	Add:Right Fields:Before:DSP VchTypeTitle : CC_LedgereInvoiceStatusv
	Local:Field:CC_LedgereInvoiceStatusv : Set as: ""

[#Line: DSP VchAccTitles]
	Add:Option:vvvnEnable_TrackeInvoiceStatus : @@Enable_TrackeInvoiceStatus
	
[!Line:vvvnEnable_TrackeInvoiceStatus]
	Add:Right Fields:Before:DSP VchTypeTitle : CC_LedgereInvoiceStatusv

[Field: CC_LedgereInvoiceStatusv]
	Use         	: Name Field
    Width       	: 45 mm
    Set as      	: "e-Invoice Status"
    Style       	: Small Bold
	Invisible		: NOT ##Show_eInvoiceStatusSalesRegister
   	
[#Line: DSP VchDetail]
	Add:Option:vvvnEnable_TrackeInvoiceStatus2:@@Enable_TrackeInvoiceStatus
	
[!Line:vvvnEnable_TrackeInvoiceStatus2]
	Add:Right Fields:Before:DSP VchType : CC_LedgereInvoiceStatus

[Field: CC_LedgereInvoiceStatus]
    Use         	: Name Field
    Width       	: 45 mm
    Set as			: @@IsGSTeInvVchStatus
    Style       	: Small Bold
	Invisible		: NOT ##Show_eInvoiceStatusSalesRegister
	Color			: IF @@IsGSTeInvVchStatus = "Rejected" THEN "Red" ELSE IF @@IsGSTeInvVchStatus = "Pending for Generation" THEN "Blue" ELSE IF @@IsGSTeInvVchStatus = "Generated without QR Code" THEN "RulerGrey" ELSE IF @@IsGSTeInvVchStatus = "Cancelled" THEN "DAS_eInvoiceStatus_StatusVar_BG" ELSE IF @@IsGSTeInvVchStatus = "Not Applicable" THEN "DarkGreen" ELSE "black"
	
[System:Formulas]
	CC_GSTeInvVchStatusFormat		: "%s"

[#Report: Daybook]
	Add:Variable : CC_eInvoiceStatusSearch

[#Report: Voucher Register]
	Add:Variable : CC_eInvoiceStatusSearch
	
;Form

;[#Form:Day book]
;	Add:Option:vvvnEnable_TrackeInvoiceStatusvv:@@Enable_TrackeInvoiceStatus

[!Form:vvvnEnable_TrackeInvoiceStatusvv]
	Button:   CC_eInvoiceStatusSearchh 
	
[Button: CC_eInvoiceStatusSearchh]
    Title : "e-Invoice Status Search"
	Action 	: ModifyVariables : CC_eInvoiceStatusSearchh	
	Key		: Ctrl + 3
	Inactive: NOT ##VoucherTypeName = "Sales"

[Report	: CC_eInvoiceStatusSearchh]
	Title : "e-Invoice Status Search"
	Form	 : CC_eInvoiceStatusSearchh
	Variable : CC_eInvoiceStatusSearch
	
	[Form	: CC_eInvoiceStatusSearchh]
		Part	: CC_eInvoiceStatusSearch
		
[Button: CC_eInvoiceStatusSearch]
    Title : "Vehicle No Search"
	Action 	: ModifyVariables  : CC_eInvoiceStatusSearch	
	Key		: Ctrl + V
	Inactive: NOT ##VoucherTypeName = "Sales"

[Variable:  CC_eInvoiceStatusSearch]
	Type		: String
	Default 	: ""

[Report	: CC_eInvoiceStatusSearch]
	Title : "eInvoiceStatus Search"
	Form	 : CC_eInvoiceStatusSearch
	Variable : CC_eInvoiceStatusSearch
	
	[Form	: CC_eInvoiceStatusSearch]
		Part	: CC_eInvoiceStatusSearch
	
		[Part	: CC_eInvoiceStatusSearch]
			Line	: CC_eInvoiceStatusSearch
	
			[Line: CC_eInvoiceStatusSearch]
				Field	: CC_eInvoiceStatusSearch 1,CC_eInvoiceStatusSearch 2

				[Field	: CC_eInvoiceStatusSearch 1]
				   Info 	: "e-Invoice Status Search :"
					
										  
				[Field	: CC_eInvoiceStatusSearch 2]
					Use         : Name Field
					Table		: CC_eInvoiceStatusList,All Items
					Show Table:Always
					Modifies 	: CC_eInvoiceStatusSearch : yes

[Collection:CC_eInvoiceStatusList]
	Title:"List of e-Invoice Status"

	List: "Generated with QR Code"
	List: "Generated without QR Code"
	List: "Pending for Generation"
	List: "Rejected"
	List: "Cancelled"
	List: "Not Applicable"

;[#Form: Columnar Ledger]
;	Add:Button:   CC_eInvoiceStatusSearchhC 
	
[Button: CC_eInvoiceStatusSearchhC]
    Title : "e-Invoice Status Search"
	Action 	: ModifyVariables  : CC_eInvoiceStatusSearchhC	
	Key		: Ctrl + 3
	Inactive: NOT ##VoucherTypeName = "Sales"

[Report	: CC_eInvoiceStatusSearchhC]
	Title : "e-Invoice Status Search"
	Form	 : CC_eInvoiceStatusSearchhC
	Variable : CC_eInvoiceStatusSearch
	
	[Form	: CC_eInvoiceStatusSearchhC]
		Part	: CC_eInvoiceStatusSearch


[#Report: Ledger Vouchers]
	Variable: Show_eInvoiceStatusSalesRegister
	Set		: Show_eInvoiceStatusSalesRegister : IF $$IsSales:##VoucherTypeName THEN Yes ELSE No

	Variable: DAS_eInvoiceStatus_StatusVar
	Set		: DAS_eInvoiceStatus_StatusVar	: $$SysName:AllItems
	
[#Report: Daybook]
	Variable: Show_eInvoiceStatusSalesRegister
	Set		: Show_eInvoiceStatusSalesRegister : IF $$IsSales:##VoucherTypeName THEN Yes ELSE No

	Variable: DAS_eInvoiceStatus_StatusVar
	Set		: DAS_eInvoiceStatus_StatusVar	: $$SysName:AllItems

[#Report: Voucher Register]
	Variable: Show_eInvoiceStatusSalesRegister
	Set		: Show_eInvoiceStatusSalesRegister : IF $$IsSales:##VoucherTypeName THEN Yes ELSE No

[#Form: Normal Ledger]
	Add	: Option:vEnable_TrackeInvoiceStatus:@@Enable_TrackeInvoiceStatus
		
[#Form:Day book]
	Add	: Option:vEnable_TrackeInvoiceStatus:@@Enable_TrackeInvoiceStatus

[!Form:vEnable_TrackeInvoiceStatus]
	Add	: Button 	: Show_eInvoiceStatusSalesRegister

[#Form: Columnar Ledger]
	Add:Button 	: Show_eInvoiceStatusSalesRegister	

[Variable: Show_eInvoiceStatusSalesRegister]
	Type    : Logical
	Volatile: No

[Button: Show_eInvoiceStatusSalesRegister]
    Key     : Ctrl + E
    Title   : if ##Show_eInvoiceStatusSalesRegister then "Hide e-Invoice Status" else "Show e-Invoice Status"
    Action  : Set : Show_eInvoiceStatusSalesRegister : NOT ##Show_eInvoiceStatusSalesRegister

	Option	: Show_eInvoiceStatusSalesRegister_BackgroundsBtnOp : Yes
	
[Color: Show_eInvoiceStatusSalesRegister_BackgroundsBtnOp]
	RGB			: 30,70,37

[!Button:Show_eInvoiceStatusSalesRegister_BackgroundsBtnOp]
	Background	: Show_eInvoiceStatusSalesRegister_BackgroundsBtnOp
	Color		: White
	Key Style	: Small Bold	
	Key Colour	: White
	Key Shade	: white
	Key Style	: Small bold
	Key Vertical Align:Centre
	Focus BG Colour	: White
	Focus BG Shade	: White
	Border			: thin box
	Inactive Color	: White
	Style			: Small bold

									
					